Skrypty

Ma ktoś jakieś skrypty do easyuo? Może się nimi podzielić, zatem jeśli wam się chce piszcie.

ja w kopalni jade na tym:

Kod:

; Kopactwo by Firek,
; na podstawie skryptu Trollicy Mloteczki,
; na podstawie skryptu nGz. :)

initevents
set %AL 0 ; 1 = koks Arms Lore, 0 = samo kopanie.
; Koks ten odbywa sie na kilofie.
set %JUCZNIAK 1 ; 1 = używamy juczniaka
; 0 = ruda ląduje w plecaku
; -1 = ruda jąduje NA ZIEMI
set %plecakjuk JUBSOZD ; ID plecaka w juczniaku/golemie
set %plecaknakamyki MSNARZD ; ID plecaka w juczniaku, do ktorego
; bedziemy wrzucac kamienie (granit).
; Umieszczamy do w plecaku na rude.
set %kilofek 0

; Jesli makro sie zatnie (nie bedzie nic robic) zwykle wystarczy
; kliknac LastObject lub dwuklik na kilofie. Czasem bedzie tez trzeba
; kliknac miejsce na ziemi w kopalni.
; I tyle. Have fun i pamietajcie by pilnowac swego makra! :)

set %licz 6
set %sukcesy 0
set #sysmsgcol 35

if %JUCZNIAK = 1
{
event sysmessage Kliknij juczniaka.
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %lama #ltargetid
set #lobjectid %lama
event macro 17 0
wait 1s
repeat
wait 1
until #conttype = ZJF && #contid <> #backpackid
set %plecakjuk #contid
event sysmessage Kliknij plecak do przechowania granitu.
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %plecaknakamyki #ltargetid
}
event sysmessage Wcisnij F10 by uruchomic makro.
gosub Pauza

sub Main
set %jrnl #jindex
set #ltargetz #charposz
if %kop = 8 || %kop = 17 || %kop = 18 || %kop = 19 || %kop = 20
set #ltargetx #charposx - 2
if %kop = 2 || %kop = 7 || %kop = 9 || %kop = 16 || %kop = 21
set #ltargetx #charposx - 1
if %kop = 0 || %kop = 1 || %kop = 3 || %kop = 6 || %kop = 10
set #ltargetx #charposx
if %kop = 4 || %kop = 5 || %kop = 11 || %kop = 15 || %kop = 22
set #ltargetx #charposx + 1
if %kop = 12 || %kop = 13 || %kop = 14 || %kop = 23 || %kop = 24
set #ltargetx #charposx + 2
if %kop = 10 || %kop = 20 || %kop = 21 || %kop = 22 || %kop = 23
set #ltargety #charposy - 2
if %kop = 3 || %kop = 9 || %kop = 11 || %kop = 19 || %kop = 24
set #ltargety #charposy - 1
if %kop = 0 || %kop = 2 || %kop = 4 || %kop = 8 || %kop = 12
set #ltargety #charposy
if %kop = 1 || %kop = 5 || %kop = 7 || %kop = 13 || %kop = 18
set #ltargety #charposy + 1
if %kop = 6 || %kop = 14 || %kop = 15 || %kop = 16 || %kop = 17
set #ltargety #charposy + 2
if %kop = 25
{
event sysmessage Koncze kopac. Przenies sie w inne miejsce i wcisnij F10.
set %kop 0
gosub Pauza
}
else
event sysmessage Kopie w %kop
gosub Kopacz
return

sub Kopacz
finditem NPF C_ , #charid
if #findkind <> -1
{
set #lobjectid #findid
set %kilofek #findid
}
else
{
repeat
wait 1s
finditem NPF C_ , #charid
until #findkind <> -1
set %kilofek #findid
}
if %AL = 1
{
set %licz %licz + 1
if %juczniak = 1
{
if %licz > 3
gosub ArmsLore
}
else
{
if %licz > 4
gosub ArmsLore
}
}
set #lobjectid %kilofek
event macro 17 0
repeat
wait 1
until #targcurs = 1
set #ltargetkind 2
target 1s
event macro 22 0
repeat
wait 1
until #targcurs = 0
wait 20
gosub Input
return

sub ArmsLore
repeat
event Macro 13 4
wait 10
until #targcurs = 1
target 1s
set %licz 0
set #ltargetkind 1
set #ltargetid %kilofek
repeat
event macro 22 0
wait 5
until #targcurs = 0
wait 5
set #targcurs 0
wait 5
gosub Kopacz
return

sub Input
if #jindex > %jrnl
{
set %jrnl %jrnl + 1
scanjournal %jrnl
if ameba in #journal || zywiolak in #journal
{
sound
}
if Wykopujesz in #journal
{
set %sukcesy %sukcesy + 1
if %sukcesy = 3
{
gosub Odloz
}
gosub Kopacz
}
if before in #journal
gosub Kopacz
if Rozbijasz in #journal || #journal = Nie_widzisz_tego! || mine_there in #journal || mozesz_tutaj_kopac in #journal
{
set %sukcesy 0
gosub Odloz
}
gosub Input
}
gosub Input
return

sub Odloz
set %kop %kop + 1
set %sukcesy 0
if %JUCZNIAK = 0
{
gosub Main
}
repeat
finditem DWJ C_ , #BACKPACKID
exevent drag #findid #findstack
wait 5
if %JUCZNIAK = 1
{
exevent dropc %plecakjuk
}
if %JUCZNIAK = -1
{
exevent dropg #charposx #charposy #charposz
}
wait 5
if That_item_is_too_heavy in #sysmsg
{
set #sysmsgcol 1080
event sysmessage Plecak jest juz pelny
halt
}
until #findkind = -1
repeat
finditem EVI C_ , #BACKPACKID
exevent drag #findid #findstack
wait 5

if %JUCZNIAK = 1
{
exevent dropc %plecaknakamyki
}
if %JUCZNIAK = -1
{
exevent dropg #charposx #charposy #charposz
}
wait 5
if That_item_is_too_heavy in #sysmsg
{
set #sysmsgcol 1080
event sysmessage Plecak jest juz pelny
halt
}
until #findkind = -1
gosub Main
return

sub Pauza
onHotKey F10
{
set %kop 0
set %jrnl #jindex
gosub Main
}
gosub Pauza
return

Skrypt napisany jak widac przez stara dobra trolcie i modyfikowany przez rownie starego fira nie mylic z firem Smile

Na skoksanie magerki proponuje:

Kod:

; ======================================================================
; = Magery by _del =
; = Cel : Castowanie strzalek (ponizej 30hp leczenie - w zaleznosci od =
; = skilla magery. +statystyki. W razie skonczenia sie ziol na =
; = kox / leczenie wlaczony zostaje tryb .afk -> pojawia sie okno =
; = informujace czego brakuje, nastepnie skrypt zostaje zatyrzmany=
; ======================================================================

chooseskill mage
set %magery_start #skill
set %magery_teraz #skill
chooseskill eval
set %eval_start #skill
set %eval_teraz #skill
chooseskill resist
set %resist_start #skill
set %resist_teraz #skill
chooseskill medit
set %medit_start #skill
set %medit_teraz #skill

gosub showstatistics

gosub choosebag

loop:
gosub checkspell
gosub cast
goto loop:

sub checkspell
set %spell 4 ; 4 Magic Arrow
set %manatocast 5
set %castdelay 2

set %healspell 28 ; 28 In Vas Mani
set %healmcost 11

if %currentskill < 50
{
set %healspell 3 ; 3 In Mani
set %healmcost 5
}
return

sub cast
gosub checkreagents
gosub checkhealth
gosub checkmana %manatocast
event macro 15 %spell
target 3s
event macro 23 0
gosub checkskill
wait %castdelay
return

sub checkhealth
if #hits = #maxhits
return
if #hits < 30
{
gosub checkmana %healmcost
event macro 15 %healspell
target 3s
event macro 23 0
wait 1s
goto checkhealth
}
return

sub checkmana
if #mana < %1
{
medit:
scanjournal 1
if You_must_wait_to in #journal
{ wait 1s
goto medit
}
event macro 13 46
set %medstart #scnt
wait 5s
if #mana < #maxmana
goto medit
}
return

sub checkreagents
set %healregs RZF_MZF_JZF_KZF
finditem SZF C
if #findkind = -1
{
sound
msg .afk$
display Skonczyly sie ziola [Siarka].
halt
}
finditem %healregs C
if #findkind = -1
{
sound
msg .afk$
display Skonczyly sie ziola [Mandra\Czosnek\Pajeczyna\Zen-Szen].
halt
}
return

sub checkskill
chooseskill mage
if #skill > %magery_teraz
{
set %magery_teraz #skill
str len %magery_teraz
str ins %magery_teraz #dot #strRes
menu delete currentskill
menu text currentskill 68 10 #strRes
set %totalgains %magery_teraz - %magery_start
str len %totalgains
str ins %totalgains #dot #strRes
menu delete totalgains
menu text totalgains 68 25 #strRes
}
chooseskill eval
if #skill > %eval_teraz
{
set %eval_teraz #skill
str len %eval_teraz
str ins %eval_teraz #dot #strRes
menu delete currentskille
menu text currentskille 68 40 #strRes
set %totalgainse %eval_teraz - %eval_start
str len %totalgainse
str ins %totalgainse #dot #strRes
menu delete totalgainse
menu text totalgainse 68 55 #strRes
}
chooseskill resist
if #skill > %resist_teraz
{
set %resist_teraz #skill
str len %resist_teraz
str ins %resist_teraz #dot #strRes
menu delete currentskillr
menu text currentskillr 68 70 #strRes
set %totalgainsr %resist_teraz - %resist_start
str len %totalgainsr
str ins %totalgainsr #dot #strRes
menu delete totalgainsr
menu text totalgainsr 68 85 #strRes
}
chooseskill medit
if #skill > %medit_teraz
{
set %medit_teraz #skill
str len %medit_teraz
str ins %medit_teraz #dot #strRes
menu delete currentskillm
menu text currentskillm 68 100 #strRes
set %totalgainsm %medit_teraz - %medit_start
str len %totalgainsm
str ins %totalgainsm #dot #strRes
menu delete totalgainsm
menu text totalgainsm 68 115 #strRes
}
return

sub showstatistics
menu clear
menu window title Makro Magery
menu window size 180 140
menu window color white
menu font bgcolor white
menu font size 8
menu font color black
menu text mageryskill 5 10 Magery:
menu text gains 5 25 Mage gains:
menu font color green
str len %magery_teraz
str ins %magery_teraz #dot #strRes
menu delete currentskill
menu text currentskill 68 10 #strRes
set %totalgains %magery_teraz - %magery_start
str len %totalgains
str ins %totalgains #dot #strRes
menu delete totalgains
menu text totalgains 68 25 #strRes

menu font color black
menu text evalskill 5 40 Eval:
menu text gainse 5 55 Eval gains:
menu font color green
str len %eval_teraz
str ins %eval_teraz #dot #strRes
menu delete currentskille
menu text currentskille 68 40 #strRes
set %totalgainse %eval_teraz - %eval_start
str len %totalgainse
str ins %totalgainse #dot #strRes
menu delete totalgainse
menu text totalgainse 68 55 #strRes

menu font color black
menu text resistskill 5 70 Resist:
menu text gainsr 5 85 Resist gains:
menu font color green
str len %resist_teraz
str ins %resist_teraz #dot #strRes
menu delete currentskillr
menu text currentskillr 68 70 #strRes
set %totalgainsr %resist_teraz - %resist_start
str len %totalgainsr
str ins %totalgainsr #dot #strRes
menu delete totalgainsr
menu text totalgainsr 68 85 #strRes

menu font color black
menu text meditskill 5 100 Medit:
menu text gainsm 5 115 Medit gains:
menu font color green
str len %medit_teraz
str ins %medit_teraz #dot #strRes
menu delete currentskillm
menu text currentskillm 68 100 #strRes
set %totalgainm %medit_teraz - %medit_start
str len %totalgainm
str ins %totalgainm #dot #strRes
menu delete totalgainm
menu text totalgainm 68 115 #strRes
menu show
return

sub choosebag
event sysmessage Kliknij torbe/pudelko z ziolami.
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %torba #ltargetid
set #lobjectid %torba
event macro 17 0
wait 1s
set #lobjectid %torba
event Macro 17 0
wait 10
return

Ten oto skrypt napisal _del Smile

Ten skrypt pomagal w przelewaniu butli do kega (wiem jest razor ale co tam)

Kod:

event sysmessage Przeciagnij odpowiednia butelke i wcisnij F10
set %stop 0
repeat
onHotKey F10
set %stop 1
until %stop = 1
set %butelki #lliftedtype
event sysmessage Kliknij keg
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %keg #ltargetid
wait 1s
gosub Main

sub Main
finditem %butelki C_ , #backpackid
if #findkind <> -1
{
exevent drag #findid #findstack
wait 5
exevent dropc %keg
wait 5
if will_not_hold in #sysmsg
{
event sysmessage Plecak jest juz pelny
halt
}
}
gosub Main
return

Chyba tez autorstwa firka

I cos jesio dla hidownikow i stelfownikow Smile

Kod:

initevents
set %max_krokow 10
set %krok 0
start:
set %czas 201
set %rand #random % 5
set %czas %czas + %rand

event Macro 13 21
wait 20
if H in #charStatus
{
goto stealth
}
wait %czas
goto start

stealth:
wait %czas + 20
event Macro 13 47
wait 20
if H in #charStatus
{
goto walk
}
wait %czas
goto start
walk:
if #CharDir = 0
{
if %krok <= %max_krokow
{
   key PGUP
   set %krok %krok + 1
}
else
{
   key END
   set %krok 0
}
}
if #CharDir = 6
{
if %krok <= %max_krokow
{
   key HOME
   set %krok %krok + 1
}
else
{
   key PGDN
   set %krok 0
}
}
if #CharDir = 4
{
if %krok <= %max_krokow
{
   key END
   set %krok %krok + 1
}
else
{
   key PGUP
   set %krok 0
}
}
if #CharDir = 2
{
if %krok <= %max_krokow
{
   key PGDN
   set %krok %krok + 1
}
else
{
   key HOME
   set %krok 0
}
}
goto stealth

ale kto napisal pojecia brak Smile

good luck

Cos dla skryby by Deathek :*

Kod:

;=========== Power Scroll Writer ===========
; Written by: Deathek (Deathek@gmail.com)
; "Deathek" at irc.ircnet.pl or GG: 1710169
; Any problems - feel free to write me
;===========================================

;===========================================
; If you want to run configuration, because
; you would like to change some coordinates
; or mana amounts, set this to #true
;===========================================
set %config #false
;===========================================
; If script is running NOT for the first
; time, set this value to #true if you want
; to use the last used bagsub
;===========================================
set %lastUsedBag #false
;===========================================
; If you want to write the whole spellbook
; Set this value to #true
;===========================================
set %FullSpellBook #true
;===========================================
; If you are NOT playing on the OSI server
; and you need to point blank scrolls every
; time after using the ink, set this value
; to #true, and write down messages, which
; you get afer success or failure
;===========================================
set %InkTarget #true
set %success Stworzyles_zwoj_i_wlozyles_go_do_plecaka.
set %failure Nie_udalo_Ci_sie_i_zniszczyles_zwoj.
;===========================================
; Set Circle and Spell you want to write
; (e.g. Circle 1 spell 5 it's Magic Arrow)
; Set amount of scrolls you want to do
; (-1 = infinitive)
;===========================================
set %circle 7
set %spell 3
set %Amount -1
;===========================================
; This is the end of configuration.
; Happy writing and fast gains :)
;===========================================

if %config = #true
set *firstPSWrun 0
if *firstPSWrun = 0 || *firstPSWrun = N/A
{
set *firstPSWrun -1
gosub configuration
menu window title Mana
menu window size 200 235
menu window color black
menu font size 8
menu font color lime
menu Font BGColor black
menu font align left
menu text info 5 2 Set amount of mana needed to write
menu text info2 5 15 a scroll from the specific circle:
menu text text1 40 33 1st Circle
menu text text2 40 55 2nd Circle
menu text text3 40 77 3rd Circle
menu text text4 40 99 4th Circle
menu text text5 40 121 5th Circle
menu text text6 40 143 6th Circle
menu text text7 40 165 7th Circle
menu text text8 40 187 8th Circle
menu edit edit1 5 30 30 *k1
menu edit edit2 5 52 30 *k2
menu edit edit3 5 74 30 *k3
menu edit edit4 5 96 30 *k4
menu edit edit5 5 118 30 *k5
menu edit edit6 5 140 30 *k6
menu edit edit7 5 162 30 *k7
menu edit edit8 5 184 30 *k8
menu font color black
menu font bgcolor lime
menu button done 150 210 45 22 DONE
menu show
repeat
wait 10
until #menubutton = done
for %t 1 8
{
menu get edit , %t
set *k . %t #menuRes
}
menu hide
}

sub configuration
for %i 1 8
{
event sysmessage Point the %i , #dot circle button and hit enter
hotk:
onhotkey ENTER
goto circle
goto hotk
circle:
set *kx . %i #cursorx
set *ky . %i #cursory
wait 5
}
for %j 1 8
{
event sysmessage Point the %j , #dot spell button and hit enter
hotc:
onhotkey ENTER
goto spell
goto hotc
spell:
set *cx . %j #cursorx
set *cy . %j #cursory
wait 5
}
event sysmessage Point the CloseMenu button and hit enter
hotclose:
onhotkey ENTER
goto close
goto hotclose
close:
set *closex #cursorx
set *closey #cursory
wait 5

event sysmessage Point the DoLast button and hit enter
hotlast:
onhotkey ENTER
goto last
goto hotlast
last:
set *lastx #cursorx
set *lasty #cursory
wait 5

event sysmessage Open the inscription gump menu, make it active (on top) and hit enter
hotmenu:
onhotkey ENTER
goto menu
goto hotmenu
menu:
set *size #contsize
wait 5
return

for %h 1 8
{
namespace local xy , %h
set !kx *kx . %h
set !ky *ky . %h
set !cx *cx . %h
set !cy *cy . %h
}

set %CloseButtonx *closex
set %CloseButtony *closey
set %DoLastButtonx *lastx
set %DoLastButtony *lasty

;===========================================
; Spell itemtypes. I suggest do not change
; anything in this section.
;===========================================
set %_1 QXL ;Clumsy
set %_2 PXL_NXL ;Create Food
set %_3 AYL ;Feeblemind
set %_4 ZXL ;Heal
set %_5 CYL ;Magic Arrow
set %_6 BYL ;Night Sight
set %_7 NXL ;Reactive Armor
set %_8 WXL_WXL ;Weaken
set %_9 VXL ;Agility
set %_10 YXL ;Cunning
set %_11 XXL ;Cure
set %_12 IYL ;Harm
set %_13 HYL ;Magic Trap
set %_14 KYL ;Magic Untrap
set %_15 JYL ;Protection
set %_16 EYL ;Strenght
set %_17 DYL ;Bless
set %_18 GYL ;Fireball
set %_19 FYL ;Magic Lock
set %_20 STL ;Posion
set %_21 RTL ;Telekinesis
set %_22 UTL ;Teleport
set %_23 TTL ;Magic Unlock
set %_24 OTL ;Wall of Stone
set %_25 NTL ;Archcure
set %_26 QTL ;Archprotecion
set %_27 PTL ;Curse
set %_28 AUL ;Fire Field
set %_29 ZTL ;Greater Heal
set %_30 CUL ;Lighting
set %_31 BUL ;Manadrain
set %_32 WTL ;Recall
set %_33 VTL ;Blade Spirit
set %_34 YTL ;Dispel Field
set %_35 XTL ;Incognito
set %_36 IUL ;Magic Reflection
set %_37 HUL ;Mind Blast
set %_38 KUL ;Paralyze
set %_39 JUL ;Poison Field
set %_40 EUL ;Summon Creature
set %_41 DUL ;Dispel
set %_42 GUL ;Energy Bolt
set %_43 FUL ;Explosion
set %_44 QUL ;Invisibility
set %_45 PUL ;Mark
set %_46 SUL ;Mass Curse
set %_47 RUL ;Paralyze Field
set %_48 MUL ;Reveal
set %_49 LUL ;Chain Lighting
set %_50 OUL ;Energy Field
set %_51 NUL ;Flamestrike
set %_52 YUL ;Gate Travel
set %_53 XUL ;Mana Vampire
set %_54 AVL ;Mass Dispel
set %_55 ZUL ;Meteor Swarm
set %_56 UUL ;Polymorph
set %_57 TUL ;Easrthquake
set %_58 WUL ;Energy Vortex
set %_59 VUL ;Resurrectiom
set %_60 GVL ;Summon Air Elemental
set %_61 FVL ;Summon Daemon
set %_62 IVL ;Summon Earth Elemental
set %_63 HVL ;Summon Fire Elemental
set %_64 CVL ;Summon Water Elemental

sub bag
if %lastUsedBag = #true
{
set %bag *LastBag
goto retbag
}
set #targcurs 1
event sysmessage Target the bag with scrolls, pens etc.
repeat
wait 10
until #targcurs = 0
set %bag #ltargetid
set *LastBag %bag
retbag:
return

sub FullSpellBook
gosub scrolle fullbook
startfull:
gosub pen
if #contsize <> *size
goto startfull
for %i 1 8
{
for %j 1 8
{
spell:
if #mana < *k . %i
{
click %CloseButtonx %CloseButtony
gosub medit
}
if %InkTarget = #true && #contsize <> *size
{
repeat
gosub pen
until #contsize = *size
}
namespace local xy , %i
click !kx !ky
set %scnt #scnt
repeat
wait 10
until #contsize = *size || #scnt - %scnt >= 5
if #scnt - %scnt >= 5
goto spell
namespace local xy , %j
click !cx !cy
repeat
wait 1
until #contsize = *size || #sysmsg = %failure || #sysmsg = %success
set %f ( ( %i - 1 ) * 8 ) + %j
finditem %_ . %f C_ , #backpackid
if #findkind = -1
{
finditem %_ . %f C_ , %bag
if #findkind = -1
goto spell
}
}
}
return

sub medit
med:
event macro 13 46
set %scnt #scnt
repeat
{
wait 20
}
until #mana = #maxmana || perform in #sysmsg || #scnt - %scnt >= 15
if #mana < #maxmana
goto med
if %InkTarget = #true
goto retmed
gosub pen
retmed:
return

sub pen
finditem CXF_PBG_ C_ , %bag
if #findkind = -1
{
display ok Out of pens.
halt
}
set #lobjectid #findid
set %ink #findid
event macro 17
if %InkTarget = #true
{
set %scnt #scnt
set #ltargetkind 1
set #ltargetid %scrolle
repeat
wait 10
until #targcurs = 1 || #scnt - %scnt >= 5
event macro 22
}
set %scnt #scnt
repeat
wait 10
until #CONTSIZE = *size || #scnt - %scnt >= 5
return

sub do_once
gosub scrolle doonce
startonce:
gosub pen
if #contsize <> *size
goto startonce
spellonce:
if #mana < *k . %1
{
click %CloseButtonx %CloseButtony
gosub medit
}
namespace local xy , %circle
click !kx !ky
set %scnt #scnt
repeat
wait 10
until #contsize = *size || #scnt - %scnt >= 5
if #scnt - %scnt >= 5
goto spellonce
namespace local xy , %spell
click !cx !cy
repeat
wait 1
until #contsize = *size || tool in #sysmsg || #sysmsg = %failure || #sysmsg = %success
return

sub do_last
repeat
{
gosub scrolle
if #mana < *k . %1
{
click %CloseButtonx %CloseButtony
gosub medit
}
if %InkTarget = #true
{
repeat
gosub pen
until #contsize = *size
}
click %DoLastButtonx %DoLastButtony
set %scnt #scnt
repeat
wait 1
until #contsize = *size || #sysmsg = %failure || #sysmsg = %success
finditem %ink
if #findkind = -1
gosub pen
set %f ( ( %1 - 1 ) * 8 ) + %2
finditem %_ . %f C_ , #backpackid
if #findkind = -1
{
finditem %_ . %f C_ , %bag
set %stack #findstack
}
else
{
set %stack #findstack
}
}
until %stack = %Amount
return

sub scrolle
finditem MMF C_ , %bag
set %scrolle #findid

if #findstack = 0
{
event sysmessage You have ran out of blank scrolls.
wait 10
event sysmessage Script stopped.
halt
}
if %1 = doonce
{
if #findstack < %Amount
{
event sysmessage You haven't got enough scrolls!
wait 10
event sysmessage You should have at least %Amount blank scrolls.
wait 10
event sysmessage Script stopped.
halt
}
}
return
;============================================

gosub bag
if %FullSpellBook = #true
{
gosub FullSpellBook
}
else
{
gosub do_once
gosub do_last %circle %spell
}
halt

NOWOŚĆ !! - SKRYPT NA ZIELARSTWO

Mam tutaj dla was (przez niektórych długo oczekiwany) skrypt na zielarstwo. Naszło mnie ostatnio coś na skryptowanie i pozwoliłem sobie przerobić skrypt na górnictwo(od Firka) na skrypt na zielarstwo. Nie dodałem jeszcze kilku ID'ków ziół, których nie zdołałem wykopać (z racji tego, że mam mało skilla), ale z czasem będę aktualizował ten post wklejając je do skryptu.

Większość uwag dot. skryptu jest w nim już zawarta, tak więc wystarczy przeczytać początek ze zrozumieniem i odpalić Wink

. Dodam tylko, że z początku trudno będzie wam coś wykopać(nigdzie nie będziecie mogli znaleść ziół), więc trochę się nawciskacie F9 i F10. Smile

Z początku kopcie na zielonej trawie(z czasem przerzucajcie się na inne tereny). Polecam kopanie na otwartych przestrzeniach, gdzie nie ma żadnych budynków.

Mój skrypt być może będzie zachętą dla ludzi, którzy chcieli kiedyś być zielarzami, ale zabrakło im siły i samozaparcia do koxu tak bardzo opornego skilla. Wbrew obiegowej opinii, zielarstwo jest bardzo dochodowym źródłem zarobku na naszym serwerze (szczególnie dla młodych postaci), bo zioła możecie sprzedać do NPC zielarzy po bardzo przyzwoitej cenie, a także możecie wykopać zioła, które są dziś tak bardzo potrzebne i trudne do zdobycia (m.in. żeń-szeń do kegów leczenia).

Poniżej macie skrypt, miłej lektury:

Kod:

;skrypt na zielarkę (przerobiony ze skryptu Firka na mining) by merq

initevents

tile init
set %odloz 1 ; 1 - używamy juczniaka lub golema (do których wkładamy plecak na zioła)
; 2 - nie używamy juków, a zioła po wykopaniu zostają w naszym glównym plecaku
; 3 - nie używamy juków, a zioła po wykopaniu lądują w plecaku włożonym do głównego plecaka

set %config 0 ; 1 - makro na początku pyta nas o golema, plecaki itp
; 0 - IDki podajemy samemu (poniżej), makro od razu zaczyna wydobywać zioła(POLECAM!)

set %tragarz RKFAM
set %plecaknaziola UHYDYHE
goto config

; Jesli po wcisnieciu F10 wyskoczy wam w journalu "Nie mozesz tu niczego znalesc"
; to znaczy, ze w tym miejscu nie ma zadnych ziol. W tym momencie musisz
; wcisnac F10, by zakonczyc dzialanie skryptu, przeniesc sie w inne miejsce
; i wcisnac F9 by ponownie go uruchomic.

start:
gosub UstawXY
repeat
gosub Kop
gosub Odloz
gosub Input
until %koniec = 1
goto start

sub UstawXY
repeat
set %kop %kop + 1
if %kop > 24
{
gosub Odloz
event SysMessage Przenies sie w inne miejsce i wcisnij F9.
gosub Pauza
set %kop 0
}
if %kop = 8 || %kop = 17 || %kop = 18 || %kop = 19 || %kop = 20
set #ltargetx #charposx - 2
if %kop = 2 || %kop = 7 || %kop = 9 || %kop = 16 || %kop = 21
set #ltargetx #charposx - 1
if %kop = 0 || %kop = 1 || %kop = 3 || %kop = 6 || %kop = 10
set #ltargetx #charposx
if %kop = 4 || %kop = 5 || %kop = 11 || %kop = 15 || %kop = 22
set #ltargetx #charposx + 1
if %kop = 12 || %kop = 13 || %kop = 14 || %kop = 23 || %kop = 24
set #ltargetx #charposx + 2
if %kop = 10 || %kop = 20 || %kop = 21 || %kop = 22 || %kop = 23
set #ltargety #charposy - 2
if %kop = 3 || %kop = 9 || %kop = 11 || %kop = 19 || %kop = 24
set #ltargety #charposy - 1
if %kop = 0 || %kop = 2 || %kop = 4 || %kop = 8 || %kop = 12
set #ltargety #charposy
if %kop = 1 || %kop = 5 || %kop = 7 || %kop = 13 || %kop = 18
set #ltargety #charposy + 1
if %kop = 6 || %kop = 14 || %kop = 15 || %kop = 16 || %kop = 17
set #ltargety #charposy + 2
tile cnt #ltargetx #ltargety
for %i 1 #tilecnt
{
tile get #ltargetx #ltargety %i
set %ok 0
) set %ok 1
{
set %ok 1
}
if %ok = 1
{
set #ltargetz #tilez
set #ltargettile #tiletype
set #ltargetkind 2
event SysMessage Szukam ziol w %kop
break
}
}
until %ok = 1
set %koniec 0
set %sukcesy 0
return

sub Kop
finditem WSF C_ , #backpackID
if #FINDKIND <> -1
{
set #LOBJECTID #FINDID
}
else
{
event SysMessage Wloz nozyk zielarski do glownego plecaka.
repeat
finditem WSF C_ , #backpackID
wait 1s
until #FINDKIND <> -1
set #LOBJECTID #FINDID
}
gosub Macro 17 0 1
set %jrnl #jindex
set #ltargetkind 2
target 1s
gosub Macro 22 0 0
return

sub Macro
set %tempmacro 0
repeat
event Macro %1 %2
repeat
set %tempmacro %tempmacro + 1
wait 1

onHotKey F10
goto config

if %tempmacro = 20
{
set %tempmacro 0
event macro %1 0
}
until #targcurs = %3
until #targcurs = %3
return

sub WskazItem
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
wait 10
return

sub Odloz
if %odloz = 2
{
return
}

if %odloz = 3
{
finditem HUF_NZF_JUF_RZF_SZF_XZF C_ , #BACKPACKID
if #FINDKIND <> -1
{
set %TEMP #FINDID
wait 1
exevent drag #FINDID #findstack
wait 5
}
exevent dropc %plecaknaziola
}

if %odloz = 1
{
repeat
finditem HUF_NZF_JUF_RZF_SZF_XZF C_ , #BACKPACKID
if #FINDKIND <> -1
{
if #FINDID = %temp
{
set #LOBJECTID %tragarz
event Macro 17 0
wait 10
}
else
set %TEMP #FINDID
wait 1
exevent drag #FINDID #findstack
wait 5
if %odloz = 1
{
exevent dropc %plecaknaziola
}
wait 5
if That_item_is_too_heavy in #sysmsg
{
event SysMessage Plecak jest juz pelny.
halt
}
}
until #FINDKIND = -1
}
repeat
finditem EVI C_ , #BACKPACKID
if #FINDKIND <> -1
until #FINDKIND = -1
return

sub Input
set %koniec 0
repeat
if #JINDEX > %jrnl
{
set %jrnl %jrnl + 1
scanjournal %jrnl

if Zakonczono_prace in #JOURNAL || Nie_udalo_ci_sie_zebrac_nic_pozytecznego in #JOURNAL
{
set %koniec 0
set %sukcesy %sukcesy + 1
break
}

if #JOURNAL = Nie_mozesz_dosiegnac || Nie_ma_tu_nic_pozytecznego in #JOURNAL || Nie_znaleziono_niczego_przydatnego in #JOURNAL
{
set %koniec 1
break
}
}
until 0 = 1
return

sub Pauza
repeat
onHotKey F9
break
until 0 = 1
return

config:
if %config = 0 || %config = 1
{
event SysMessage Wcisnij F9 by wlaczyc skrypt. Wcisniecie F10 spowoduje zatrzymanie sktyptu.
gosub Pauza
}

if %config = 1
{
if %odloz = 3
{
event SysMessage Wskaz plecak na ziola.
gosub WskazItem
set %plecaknaziola #LTARGETID
set #LOBJECTID %plecaknaziola
wait 10
event Macro 17 0
wait 5
}

if %odloz = 1
{
event SysMessage Wskaz juczniaka lub golema.
gosub WskazItem
set %tragarz #LTARGETID
set #LOBJECTID %tragarz
event Macro 17 0
wait 1s
repeat
wait 1
until #conttype = ZJF && #contid <> #backpackid
set %plecaknaziola #contid
if %odloz = 1
{
wait 10
event SysMessage Wskaz plecak na ziola.
gosub WskazItem
set %plecaknaziola #LTARGETID
set #LOBJECTID %plecaknaziola
wait 10
event Macro 17 0
wait 5
}
}
}
set %sukcesy 0
set %TEMP 666
set #sysmsgcol 15
set %jrnl #JINDEX
set %tempx -3
set %tempy -2
set %tempczas 0
set %koniec 1
set %tempczas #time + 10
set %kop 0
goto start

Merq

Trzeba było jeszcze dodać, że to skrypt dla wszystkich zielarzy na serwerze Very Happy

(sory za offtop, nie mogłem się powstrzymać)

;]