Skrypt - Górnictwo i Drwalstwo

szukam skryptu na gornictwo dzialajacego na 096, ma ktos?

Był już taki temat kiedyś i odpowiedzieli że najwyżej dadzą Last object Last target czy jakoś tak

wielkie dzieki Smile

Jestem z dziwiony ale zarazem dziekuje;) skopiuje se zanim to usuna;D

Usunąć to tu trzeba coś innego... a raczej kogoś...

Popieram Zasoov

Skasowałem stare posty.

Skrypt umożliwia równoległy koks Arms Lore lub EvalINT (w zależności od wartości zmiennej %koks).

W zależności od ustawionej wartości zmiennej %JUCZNIAK można:
- wrzucać rudę i kamyki do juczniaka (potrzebny jest osobny pojemnik na granit wewnątrz juków, by ich nie zaśmiecać)
- zostawiać rudę i granit w plecaku
- zostawiać rudę w plecaku a granit chować do osobnego pojemnika w plecaku
- upuszczać na ziemię (dla kopaczy siły i nie tylko Razz

).
- używać golema (z osobnym pojemnikiem na rudę - żeby się nie rozsypywała po "golem zamiana")

Poniżej zamieszczam nową wersję, wymagającą spolszczonego pliku cliloc.enu (do pobrania z [link widoczny dla zalogowanych]). W odróżnieniu od poprzedniego jest kompletnie idiotoodporny Wink

tj. nie trzeba ustawiać żadnych IDków.

Jeśli złamie się nam kilof wkładamy do rąk nowy. Skrypt powinien normalnie wrócić do pracy.

Jeśli mamy kilof w dłoni a postać przestała kopać, powinno wystarczyć użycie kilofa (makro LastObject lub dwuklik na kilofie). Jeśli to jeszcze nie "ożywiło" skryptu, klikamy "celownikiem" na ziemi nieopodal postaci. Jeśli i to nie pomoże niestety trzeba wyłączyć makro i włączyć ponownie.

Jeśli makro przestanie reagować po kliknięciu juczniaka, może pomóc:
1) Kliknięcie grafiki otworzonego plecaka (juków lub "ładowni" golema)
2) Ustawienie w opcjach Ultimy (menu z myszką - prawy górny róg) następujących rzeczy:
- Zaznaczyć "Disable the Menu Bar"
- Odznaczyć "Display Item Properties Icon" (trzeba zjechać suwakiem na dół - przedostatnia opcja).

A oto i sam skrypt:

Kod:

; Kopactwo by Firek.

initevents
tile init
set %reakcja 2 ; Reakcja na wykopanie zywiolaka.
; 0 = brak reakcji.
; 1 = pijemy niewidke.
; 2 = makro zatrzymuje sie.
set %koks 2 ; 0 = nic nie koksamy - samo kopanie
; 1 = koks Arms Lore (na kilofie)
; 2 = koks EvalINT (na juczniaku/golemie)
set %JUCZNIAK 3 ; 0 = ruda ląduje w plecaku
; 1 = używamy juczniaka
; 2 = ruda ląduje w plecaku, a granit
; w osobnym pojemniku
; 3 = używamy golema (do którego wkładamy
; pojemnik na rudę oraz osobny na granit)
; -1 = ruda jąduje NA ZIEMI

; Have fun i pamietajcie by pilnowac swego makra! :)
; Dokładne instrukcje znajdziecie na forum:
; http://www.clairslair.fora.pl/offtopic,3/skrypt,861.html#9552
; W razie błędów itp. proszę je opisywać własnie tam (proszę o
; info przy jakim powiadomieniu w Journalu makro się zawiesiło).

set %licz 6
set %sukcesy 0
set %TEMP 666
set #sysmsgcol 15

if %koks = 2
{
if %juczniak = 0 || %juczniak = 2 || %juczniak = -1
{
event sysmessage Brak juczniaka - koks EvalINT niemozliwy.
set %koks 0
}
}

if %JUCZNIAK = 1 || %JUCZNIAK = 3
{
event sysmessage Kliknij juczniaka.
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %lama #ltargetid
set #lobjectid %lama
event macro 17 0
wait 1s
repeat
wait 1
until #conttype = ZJF && #contid <> #backpackid
set %plecakjuk #contid
if %JUCZNIAK = 3
{
wait 10
event sysmessage Kliknij plecak na rude
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %plecakjuk #ltargetid
set #lobjectid %plecakjuk
wait 10
event Macro 17 0
wait 5
}
}
if %JUCZNIAK = 1 || %JUCZNIAK = 2 || %JUCZNIAK = 3
{
event sysmessage Kliknij plecak do przechowania granitu.
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %plecaknakamyki #ltargetid
}

gosub Start

sub Start
gosub Pauza
set %kop 0
set %jrnl #jindex
gosub Main
return

sub Main
set %jrnl #jindex
set #ltargetz #charposz
if %kop = 8 || %kop = 17 || %kop = 18 || %kop = 19 || %kop = 20
set #ltargetx #charposx - 2
if %kop = 2 || %kop = 7 || %kop = 9 || %kop = 16 || %kop = 21
set #ltargetx #charposx - 1
if %kop = 0 || %kop = 1 || %kop = 3 || %kop = 6 || %kop = 10
set #ltargetx #charposx
if %kop = 4 || %kop = 5 || %kop = 11 || %kop = 15 || %kop = 22
set #ltargetx #charposx + 1
if %kop = 12 || %kop = 13 || %kop = 14 || %kop = 23 || %kop = 24
set #ltargetx #charposx + 2
if %kop = 10 || %kop = 20 || %kop = 21 || %kop = 22 || %kop = 23
set #ltargety #charposy - 2
if %kop = 3 || %kop = 9 || %kop = 11 || %kop = 19 || %kop = 24
set #ltargety #charposy - 1
if %kop = 0 || %kop = 2 || %kop = 4 || %kop = 8 || %kop = 12
set #ltargety #charposy
if %kop = 1 || %kop = 5 || %kop = 7 || %kop = 13 || %kop = 18
set #ltargety #charposy + 1
if %kop = 6 || %kop = 14 || %kop = 15 || %kop = 16 || %kop = 17
set #ltargety #charposy + 2
tile cnt #ltargetx #ltargety ;#curskind
set %int 1
set %stop #tileCnt
repeat
tile get #ltargetx #ltargety %int #curskind
set %int %int + 1
set %ok 0
if #tiletype = 117 || #tiletype = 222 || #tiletype = 223 || #tiletype = 471 || #tiletype = 473 || #tiletype = 474 || ( #tiletype >= 226 && #tiletype <= 231 ) || ( #tiletype >= 243 && #tiletype <= 247 ) || ( #tiletype >= 260 && #tiletype <= 263 ) || ( #tiletype >= 272 && #tiletype <= 275 ) || ( #tiletype >= 290 && #tiletype <= 293 ) || ( #tiletype >= 467 && #tiletype <= 174 ) || ( #tiletype >= 543 && #tiletype <= 560 ) || ( #tiletype >= 562 && #tiletype <= 571 ) || ( #tiletype >= 581 && #tiletype <= 585 ) || ( #tiletype >= 1741 && #tiletype <= 1745 ) || ( #tiletype >= 1754 && #tiletype <= 1757 ) || ( #tiletype >= 1771 && #tiletype <= 1778 ) || ( #tiletype >= 1787 && #tiletype <= 1788 ) || ( #tiletype >= 1805 && #tiletype <= 1812 ) || ( #tiletype >= 1821 && #tiletype <= 1824 ) || ( #tiletype >= 1835 && #tiletype <= 1842 ) || ( #tiletype >= 1851 && #tiletype <= 1854 ) || ( #tiletype >= 1865 && #tiletype <= 1867 ) || ( #tiletype >= 1869 && #tiletype <= 1872 ) || ( #tiletype >= 1881 && #tiletype <= 1884 ) ||
set %ok 1
if %ok = 1
{
set #ltargetz #tilez
set #ltargettile #tiletype
set #ltargetkind 2
set %int %stop + 666
}
until %int > %stop
if %ok = 0
{
set %kop %kop + 1
if %kop = 25
{
set %kop 0
event sysmessage Koncze kopac. Przenies sie w inne miejsce.
sound
gosub Start
}
gosub Main
}
if %kop = 25
{
event sysmessage Koncze kopac. Przenies sie w inne miejsce.
set %kop 0
sound
gosub Start
}
else
event sysmessage Kopie w %kop
gosub Kopacz
return

sub Kopacz
if %reakcja > 0
{
finditem ED G_5
if #findkind <> -1
{
if %reakcja = 1
{
finditem MUF C_
if #findkind <> -1
{
set #lobjectid #findid
event macro 17 0
}
else
event sysmessage NIE MA NIEWIDEK!
}
gosub Pauza
}
}
finditem NPF C_ , #charid
if #findkind <> -1
{
set #lobjectid #findid
}
else
{
event sysmessage Wez kilof do rency
repeat
wait 1s
finditem NPF C_ , #charid
until #findkind <> -1
set #lobjectid #findid
}
if %koks > 0
{
set %licz %licz + 1
if %juczniak = 1 || %juczniak = 3
{
if %licz > 3
gosub Koksaj
}
else
{
if %licz > 4
gosub Koksaj
}
}
set %temp 0
event macro 17 0
repeat
wait 1
set %temp %temp + 1
if %temp = 20
{
set %temp 0
event Macro 17 0
}
until #targcurs = 1
set #ltargetkind 2
target 1s
event macro 22 0
repeat
wait 1
until #targcurs = 0
gosub Input
return

sub Koksaj
repeat
if %koks = 1
event Macro 13 4
if %koks = 2
event Macro 13 16
wait 10
until #targcurs = 1
target 1s
set %licz 0
set #ltargetkind 1
finditem NPF C_ , #charid
if #findkind <> -1
{
if %koks = 1
set #ltargetid #findid
if %koks = 2
set #ltargetid %lama
}
else
{
event sysmessage Wez kilof do rency
repeat
wait 1s
finditem NPF C_ , #charid
until #findkind <> -1
set #ltargetid #findid
}
repeat
event macro 22 0
wait 5
until #targcurs = 0
wait 5
set #targcurs 0
wait 5
gosub Kopacz
return

sub Input
repeat
onhotkey esc
{
event sysmessage PAUZA
gosub Pauza
}
if #jindex > %jrnl
{
set %jrnl %jrnl + 1
scanjournal %jrnl
if ameba in #journal || zywiolak in #journal
{
sound
}
if Wykopujesz in #journal
{
set %sukcesy %sukcesy + 1
if %sukcesy = 3
{
gosub Odloz
}
gosub Kopacz
}
if before in #journal
gosub Kopacz
if Rozbijasz in #journal
{
set %sukcesy 0
gosub Odloz
}
if #journal = Nie_widzisz_tego! || mine_there in #journal || mozesz_tutaj_kopac in #journal || Nie_mozna in #journal || daleko in #journal
{
set %licz %licz - 1
set %sukcesy 0
gosub Odloz
}
}
until %start = 666
return

sub Odloz
set %kop %kop + 1
set %sukcesy 0
if %JUCZNIAK = 0
{
gosub Main
}
if %JUCZNIAK <> 2
{
repeat
onhotkey esc
{
event sysmessage PAUZA
pause
}
finditem DWJ C_ , #BACKPACKID
if #findkind <> -1
{
if #findid = %temp
{
set #lobjectid %lama
event Macro 17 0
wait 10
}
else
set %TEMP #findid
exevent drag #findid #findstack
wait 5
if %JUCZNIAK = 1 || %JUCZNIAK = 3
{
exevent dropc %plecakjuk
}
if %JUCZNIAK = -1
{
exevent dropg #charposx #charposy #charposz
}
wait 5
if That_item_is_too_heavy in #sysmsg
{
event sysmessage Plecak jest juz pelny
halt
}
}
until #findkind = -1
}
repeat
onhotkey esc
{
event sysmessage PAUZA
pause
}
finditem EVI C_ , #BACKPACKID
if #findkind <> -1
{
exevent drag #findid #findstack
wait 5
if %JUCZNIAK = 1 || %JUCZNIAK = 2 || %JUCZNIAK = 3
{
exevent dropc %plecaknakamyki
}
wait 5
if That_item_is_too_heavy in #sysmsg
{
event sysmessage Plecak jest juz pelny
halt
}
}
until #findkind = -1
gosub Main
return

sub Pauza
set %start 0
event sysmessage Wcisnij F10 by kontynuowac.
repeat
onHotKey F10
set %start 1
until %start = 1
return

Cytat:

(...) lub upuszczać na ziemię (...)

Nie polecam ;]

Hmm? Że zaśmiecanie serwera czy że nie wolno bo to jawny koks a to niedobre? Smile

Tak wrzuciłem bo to kilka linijek w może się komu przyda... Razz

Głównie za zaśmiecanie ;]

Ale są też inne powody ;]

Nie żebym był ivil czy coś.... ale Barczar... no wiecie jak to jest... ;]]]]

Bump oraz wprowadziłem kilka poprawek:
- Uzywanie Arms Lore powinno działać bez problemów.
- Kopanie bez juczniaka/golema powinno działać bez problemów.
- Wprowadziłem zmienną %otwierajjuczniaka, opis kilka ekranów wyżej, nad kodem skryptu

Doszlifowałem trochę mój skromny skrypt na Lumberjacking. Jedyne co robi to używa siekiery i czeka, aż klikniemy celowniczkiem drzewo. Następnie wycina je do końca (10 udanych uderzeń lub do komunikatu że nie ma więcej drewna) i wrzuca drewno do juczniaka (czy innego golema). Na koniec znów używa siekierki i czeka aż klikniemy następne drzewo. I tak w kółko. Smile

Nie jakaś tam burżujska full automatyzacja z podchodzeniem do drzewka, przynajmniej macie motywację, żeby pilnować makra. Razz

Więc włączcie sobie Always on Top w Media Playerze i klikajcie aż wam paluchy spuchną. Razz

Parametry i rozwiązywanie problemów (zepsute narzędzie, zwis skryptu itp) podobnie jak w Kopactwie (patrz kilka ekranów wyżej).

Kod:

; Lumberka by Firek

initevents
set %sukcesy 0
set #sysmsgcol 35

set %JUCZNIAK 1 ; 1 = używamy juczniaka
; 0 = drewno trafia do plecaka
; -1 = drewmo jąduje NA ZIEMI
set %otwierajjuczniaka 1 ; 1 = skrypt sam otwiera juczniaka
; 0 = skrypt nie otwiera juczniaka

if %JUCZNIAK = 1
{
event sysmessage Kliknij juczniaka.
set #targcurs 1
target 50s
repeat
wait 1
until #targcurs = 0
set %lama #ltargetid
set #lobjectid %lama
event macro 17 0
wait 1s
repeat
wait 1
until #conttype = ZJF && #contid <> #backpackid
set %plecakjuk #contid
}
event sysmessage Wcisnij F10 by wlaczyc skrypt.
gosub Pauza

sub Wybierz
set %jrnl #jindex
finditem FSF C_ , #charid
if #findkind <> -1
{
set #lobjectid #findid
}
else
{
event sysmessage Wez siekierke do rency
repeat
wait 1s
finditem FSF C_ , #charid
until #findkind <> -1
set #lobjectid #findid
}
event macro 17 0
repeat
wait 1
until #targcurs = 1
gosub Input
return

sub Ciach
finditem FSF C_ , #charid
if #findkind <> -1
{
set #lobjectid #findid
}
else
{
event sysmessage Wez siekierke do rency
repeat
wait 1s
finditem FSF C_ , #charid
until #findkind <> -1
set #lobjectid #findid
}
event macro 17 0
repeat
wait 1
until #targcurs = 1
target 1s
event macro 22 0
repeat
wait 1
until #targcurs = 0
gosub Input
return

sub Input
if #jindex > %jrnl
{
set %jrnl %jrnl + 1
scanjournal %jrnl
if Wrzucasz_nieco_drewna in #journal
{
set %sukcesy %sukcesy + 1
if %sukcesy = 10
{
gosub Odloz
}
gosub Ciach
}
if Za_daleko in #journal
gosub Odloz
if before in #journal || nadawalo in #journal
{
gosub Ciach
}
if ilosci_drewna in #journal || #journal = You_can't_see_that. || worn in #journal || #journal = Nie_widzisz_tego!
{
gosub Odloz
}
gosub Input
}
gosub Input
return

sub Odloz
set %sukcesy 0
if %JUCZNIAK = 0
{
gosub Main
}
if %otwierajjuczniaka = 1
{
set #lobjectid %lama
event Macro 17 0
wait 10
}
repeat
finditem ZLK C_ , #BACKPACKID
exevent drag #findid #findstack
wait 5
if %JUCZNIAK = 1
{
exevent dropc %plecakjuk
}
if %JUCZNIAK = -1
{
exevent dropg #charposx #charposy #charposz
}
wait 5
if That_item_is_too_heavy in #sysmsg
{
set #sysmsgcol 1080
event sysmessage Plecak jest juz pelny
halt
}
until #findkind = -1
wait 5
gosub Wybierz
return

sub Pauza
onHotKey F10
{
set %jrnl #jindex
gosub Wybierz
}
gosub Pauza
return

A propo gornictwa, to ja poszukuje takiego macra ktore potrafi kopac na skalce, chyba ze tamto poprzednie tez to potrafi? Z gory dziekuje.

Ahahaha wez firek spakuj all do raru i wystaw na ftp ...... napewno pomoze to ludzikom ktorzy nie potrafia poszukac w google ... poczytac troche ... i uzupelnic scrypta :>

Korg po co te szyderstwa? Nie podoba Ci sie/nie pasuje ze ktos komus pomaga? Nie czytaj. Daruj sobie. Naprawde.